/*-----------------------------------------------------------------------------
	The contents of this file are subject to the Mozilla Public License
	Version 1.1 (the "License"); you may not use this file except in
	compliance with the License.You may obtain a copy of the License at
	http://www.mozilla.org/MPL/MPL-1.1.html
	
	Software distributed under the License is distributed on an "AS IS"
	basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See the
	License for the specific language governing rights and limitations
	under the License.
	
	The Original Code is Fever Framework code.
	
	The Initial Developer of the Original Code is Romain Ecarnot.
	Portions created by Initial Developer are Copyright (C) 2006
	the Initial Developer. All Rights Reserved.
	
	Contributor(s):
	
	Unless required by applicable law or agreed to in writing, software
	distributed under the License is distributed on an "AS IS" BASIS,
	WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
	See the License for the specific language governing permissions and
	limitations under the License.
-----------------------------------------------------------------------------*/

import com.bourre.commands.Delegate;
import com.bourre.events.DynBasicEvent;

import fever.events.FeverController;
import fever.log.FeverDebug;

/**
 * Builds bridge between SWF Timeline call and core classes.
 * 
 * <p>Timeline can call
 * <ul>
 *   <li>{@code _global.fireTimelineEvent()} method.</li>
 *   <li>{@code _global.logTimeline()} method.</li>
 * </ul>
 * <br />Call are delegate to Website classes.
 * 
 * @author Romain Ecarnot
 */
class fever.utils.TimelineProxy 
{
	//-------------------------------------------------------------------------
	// Private properties
	//-------------------------------------------------------------------------
	
	private static var _instance : TimelineProxy;
	
	
	//-------------------------------------------------------------------------
	// Public API
	//-------------------------------------------------------------------------
	
	/**
	 * Returns {@link TimelineProxy} instance.
	 */
	public static function getInstance() : TimelineProxy
	{
		if( !_instance ) _instance = new TimelineProxy();
		return _instance;	
	}
	
	/**
	 * Inits proxy.
	 * 
	 * <ul>
	 *   <li>{@code _global.fireTimelineEvent} is redirect</li>
	 *   <li>{@code _global.logTimeline} is redirect</li>
	 * </ul>
	 */
	public function init(  ) : Void
	{
		//Proxy for Timeline event dispatching
		_global.fireTimelineEvent = Delegate.create( this, _timelineEventProxy );
		
		//Proxy for Timeline logging
		_global.logTimeline = Delegate.create( this, _logTimelineProxy );
	}
	
	
	//-------------------------------------------------------------------------
	// Private implementation
	//-------------------------------------------------------------------------
	
	/**
	 * Constructor.
	 */
	private function TimelineProxy() { }	
	
	private function _timelineEventProxy( event : DynBasicEvent ) : Void 
	{
		if( !FeverController.getInstance().isRegistred( event.type ) )
		{
			FeverDebug.ERROR( 'Timeline Event type ' + event.type + ' is not registred in controller' );	
		}
		
		FeverController.getInstance().dispatchEvent( event );
	}
	
	private function _logTimelineProxy( o ) : Void
	{
		FeverDebug.INFO( '[ UI ] ' + o );
	}
	
}